Citat:
rgdrajko: Mislim da je ovako najbolje.
Kada se ovako nešto napiše, onda je ipak potrebno da se pre toga proveri, da li taj kôd moze i da radi.
Citat:
rgdrajko:
Open "Text1.txt" For Input As #1
Ova linija javlja grešku zato što nije određena putanja i nije kreiran File "Text1.txt". Ako bi ovo trebalo da služi kao primer, gde se zna šta je "pisac hteo da kaže", onda se postavlja pitanje šta će nekom ovaj primer, kada već zna o čemu je reč. A ako treba da služi da bi neko naučio nešto, onda primer treba da bude jasan i funkcionalan.
Ovo što ću sada navesti kao primer, može da posluži nekome ko je dovoljno upoznat sa bar osnovama VB-a. I pre nego što se startuje program, treba postaviti referencu "Microsoft Scripting Runtime". I još nešto...ne smatram da su ovi primeri jedini, jer ih ima još, ali nisam imao vremena da ih navodim.
Code:
Option Explicit
Dim FSobj As Scripting.FileSystemObject
Private Sub Command1_Click()
Dim TxtFile
Dim FilePath As String
FilePath = App.Path & "\ProbniFile.txt" 'Stringpromenljivoj dodeliti putanju i naziv File-a
Set FSobj = New Scripting.FileSystemObject 'Aktiviranje novog "FileSystemObject"-a
'*** Kreiranje TextFile-a koji ce posluziti i kao file za TextStream ojekat **************************
Set TxtFile = FSobj.CreateTextFile(FilePath, True) 'Kreiranje "TextFile"-a ciju putanju i naziv definise stringpromenljiva "FilePath"
TxtFile.WriteLine ("Ovo je proba!") 'Upisivanje proizvoljnog teksta u "TextFile"
TxtFile.Close
'*** Koriscenje TextStream objekta za unosenje ili izcitavanje iz TextFile-a ************************
Dim TxtFileWrite As Scripting.TextStream
Dim TxtFileRead As Scripting.TextStream
Dim TxtFileAppend As Scripting.TextStream
Dim SadrzajFile As String
Set TxtFileRead = FSobj.OpenTextFile(FilePath, ForReading) 'Aktiviranje "TextStream" objekta za izcitavanje
SadrzajFile = TxtFileRead.ReadLine 'Stringpromenljivoj "SadrzajFile" dodeliti prvu liniju iz "TextFile"-a
TxtFileRead.Close
Set TxtFileRead = FSobj.OpenTextFile(FilePath, ForReading) 'Aktiviranje "TextStream" objekta za izcitavanje
SadrzajFile = TxtFileRead.Read(1) 'Izcitavanje prvok karaktera date linije u "TextFile"-u
TxtFileRead.Close
Set TxtFileWrite = FSobj.OpenTextFile(FilePath, ForWriting) 'Aktiviranje "TextStream" objekta za upisivanje
TxtFileWrite.WriteLine "Proba1" 'Upisivanje proizvoljnog teksta u "TextFile"
TxtFileWrite.Close
Set TxtFileAppend = FSobj.OpenTextFile(FilePath, ForAppending) 'Aktiviranje "TextStream" objekta za dodavanje
TxtFileAppend.WriteLine "Proba2" 'Dodavanje proizvoljnog teksta u "TextFile"
TxtFileAppend.Close
Set TxtFile = Nothing
Set TxtFileRead = Nothing
Set TxtFileWrite = Nothing
Set TxtFileAppend = Nothing
End Sub
[Ovu poruku je menjao dennycd2 dana 02.05.2007. u 11:54 GMT+1]